Merge branch 'MON-497-docker' into 'master'

MON-497 Docker monitors: service check and memory used

See merge request claranet/pt-monitoring/projects/datadog/terraform/monitors!97

README.md

@@ -127,6 +127,7 @@ The `//` is very important, it's a terraform specific syntax used to separate gi
 ### Monitors summary ###
 
 - [caas](https://git.fr.clara.net/claranet/pt-monitoring/projects/datadog/terraform/monitors/tree/master/caas/)
+	- [docker](https://git.fr.clara.net/claranet/pt-monitoring/projects/datadog/terraform/monitors/tree/master/caas/docker/)
 	- [kubernetes](https://git.fr.clara.net/claranet/pt-monitoring/projects/datadog/terraform/monitors/tree/master/caas/kubernetes/)
 		- [ark](https://git.fr.clara.net/claranet/pt-monitoring/projects/datadog/terraform/monitors/tree/master/caas/kubernetes/ark/)
 		- [cluster](https://git.fr.clara.net/claranet/pt-monitoring/projects/datadog/terraform/monitors/tree/master/caas/kubernetes/cluster/)

caas/docker/README.md

@@ -0,0 +1,56 @@
+# CAAS DOCKER DataDog monitors
+
+## How to use this module
+
+```
+module "datadog-monitors-caas-docker" {
+  source = "git::ssh://git@git.fr.clara.net/claranet/pt-monitoring/projects/datadog/terraform/monitors.git//caas/docker?ref={revision}"
+
+  environment = var.environment
+  message     = module.datadog-message-alerting.alerting-message
+}
+
+```
+
+## Purpose
+
+Creates DataDog monitors with the following checks:
+
+- Docker Container Memory Used (disabled by default)
+- Docker does not respond
+
+## Inputs
+
+| Name | Description | Type | Default | Required |
+|------|-------------|:----:|:-----:|:-----:|
+| environment | Architecture Environment | string | n/a | yes |
+| evaluation\_delay | Delay in seconds for the metric evaluation | string | `"15"` | no |
+| filter\_tags\_custom | Tags used for custom filtering when filter_tags_use_defaults is false | string | `"*"` | no |
+| filter\_tags\_custom\_excluded | Tags excluded for custom filtering when filter_tags_use_defaults is false | string | `""` | no |
+| filter\_tags\_use\_defaults | Use default filter tags convention | string | `"true"` | no |
+| memory\_used\_enabled | Flag to enable Container Memory Usage monitor | string | `"false"` | no |
+| memory\_used\_extra\_tags | Extra tags for Container Memory Usage monitor | list(string) | `[]` | no |
+| memory\_used\_message | Custom message for the Container Memory Usage monitor | string | `""` | no |
+| memory\_used\_threshold\_critical | Container Memory Usage critical threshold | string | `"90"` | no |
+| memory\_used\_threshold\_warning | Container Memory Usage warning threshold | string | `"85"` | no |
+| memory\_used\_time\_aggregator | Time aggregator for the Container Memory Usage monitor | string | `"min"` | no |
+| memory\_used\_timeframe | Timeframe for the Container Memory Usage monitor | string | `"last_5m"` | no |
+| message | Message sent when an alert is triggered | string | n/a | yes |
+| new\_host\_delay | Delay in seconds before monitor new resource | string | `"300"` | no |
+| not\_responding\_enabled | Flag to enable Docker does not respond monitor | string | `"true"` | no |
+| not\_responding\_extra\_tags | Extra tags for Docker does not respond monitor | list(string) | `[]` | no |
+| not\_responding\_message | Custom message for Docker does not respond monitor | string | `""` | no |
+| not\_responding\_no\_data\_timeframe | Docker does not respond monitor no data timeframe | string | `"10"` | no |
+| not\_responding\_threshold\_warning | Docker does not respond monitor (warning threshold) | string | `"3"` | no |
+| prefix\_slug | Prefix string to prepend between brackets on every monitors names | string | `""` | no |
+
+## Outputs
+
+| Name | Description |
+|------|-------------|
+| memory\_used\_id | id for monitor memory_used |
+| not\_responding\_id | id for monitor not_responding |
+
+## Related documentation
+
+* [Datadog Docker integration](https://docs.datadoghq.com/integrations/docker_daemon/)

caas/docker/inputs.tf

@@ -0,0 +1,118 @@
+# Global Terraform
+variable "environment" {
+  description = "Architecture Environment"
+  type        = string
+}
+
+# Global DataDog
+variable "evaluation_delay" {
+  description = "Delay in seconds for the metric evaluation"
+  default     = 15
+}
+
+variable "new_host_delay" {
+  description = "Delay in seconds before monitor new resource"
+  default     = 300
+}
+
+variable "prefix_slug" {
+  description = "Prefix string to prepend between brackets on every monitors names"
+  default     = ""
+}
+
+variable "message" {
+  description = "Message sent when an alert is triggered"
+}
+
+variable "filter_tags_use_defaults" {
+  description = "Use default filter tags convention"
+  default     = "true"
+}
+
+variable "filter_tags_custom" {
+  description = "Tags used for custom filtering when filter_tags_use_defaults is false"
+  default     = "*"
+}
+
+variable "filter_tags_custom_excluded" {
+  description = "Tags excluded for custom filtering when filter_tags_use_defaults is false"
+  default     = ""
+}
+
+#
+# Not Responding
+#
+variable "not_responding_enabled" {
+  description = "Flag to enable Docker does not respond monitor"
+  type        = string
+  default     = "true"
+}
+
+variable "not_responding_message" {
+  description = "Custom message for Docker does not respond monitor"
+  type        = string
+  default     = ""
+}
+
+variable "not_responding_threshold_warning" {
+  description = "Docker does not respond monitor (warning threshold)"
+  type        = string
+  default     = 3
+}
+
+variable "not_responding_no_data_timeframe" {
+  description = "Docker does not respond monitor no data timeframe"
+  type        = string
+  default     = 10
+}
+
+variable "not_responding_extra_tags" {
+  description = "Extra tags for Docker does not respond monitor"
+  type        = list(string)
+  default     = []
+}
+
+#
+# Container Memory Usage
+#
+variable "memory_used_enabled" {
+  description = "Flag to enable Container Memory Usage monitor"
+  type        = string
+  default     = "false"
+}
+
+variable "memory_used_message" {
+  description = "Custom message for the Container Memory Usage monitor"
+  type        = string
+  default     = ""
+}
+
+variable "memory_used_time_aggregator" {
+  description = "Time aggregator for the Container Memory Usage monitor"
+  type        = string
+  default     = "min"
+}
+
+variable "memory_used_timeframe" {
+  description = "Timeframe for the Container Memory Usage monitor"
+  type        = string
+  default     = "last_5m"
+}
+
+variable "memory_used_threshold_warning" {
+  description = "Container Memory Usage warning threshold"
+  type        = string
+  default     = 85
+}
+
+variable "memory_used_threshold_critical" {
+  description = "Container Memory Usage critical threshold"
+  type        = string
+  default     = 90
+}
+
+variable "memory_used_extra_tags" {
+  description = "Extra tags for Container Memory Usage monitor"
+  type        = list(string)
+  default     = []
+}

caas/docker/modules.tf

@@ -0,0 +1,9 @@
+module "filter-tags" {
+  source = "../../common/filter-tags"
+
+  environment                 = var.environment
+  resource                    = "docker"
+  filter_tags_use_defaults    = var.filter_tags_use_defaults
+  filter_tags_custom          = var.filter_tags_custom
+  filter_tags_custom_excluded = var.filter_tags_custom_excluded
+}

caas/docker/monitors-docker.tf

@@ -0,0 +1,69 @@
+#
+# Service Check
+#
+resource "datadog_monitor" "not_responding" {
+  count   = var.not_responding_enabled == "true" ? 1 : 0
+  name    = "${var.prefix_slug == "" ? "" : "[${var.prefix_slug}]"}[${var.environment}] Docker does not respond"
+  message = coalesce(var.not_responding_message, var.message)
+  type    = "service check"
+
+  query = <<EOQ
+    "docker.service_up"${module.filter-tags.service_check}.by("host").last(6).count_by_status()
+EOQ
+
+  thresholds = {
+    warning  = var.not_responding_threshold_warning
+    critical = 5
+  }
+
+  new_host_delay      = var.new_host_delay
+  no_data_timeframe   = var.not_responding_no_data_timeframe
+  notify_no_data      = true
+  notify_audit        = false
+  locked              = false
+  timeout_h           = 0
+  include_tags        = true
+  require_full_window = true
+  renotify_interval   = 0
+
+  tags = concat(["env:${var.environment}", "type:docker", "provider:docker", "resource:docker", "team:claranet", "created-by:terraform"], var.not_responding_extra_tags)
+
+  lifecycle {
+    ignore_changes = ["silenced"]
+  }
+}
+
+resource "datadog_monitor" "memory_used" {
+  count   = var.memory_used_enabled == "true" ? 1 : 0
+  name    = "${var.prefix_slug == "" ? "" : "[${var.prefix_slug}]"}[${var.environment}] Docker Container Memory Used {{#is_alert}}{{{comparator}}} {{threshold}}% ({{value}}%){{/is_alert}}{{#is_warning}}{{{comparator}}} {{warn_threshold}}% ({{value}}%){{/is_warning}}"
+  message = coalesce(var.memory_used_message, var.message)
+  type    = "query alert"
+
+  query = <<EOQ
+    ${var.memory_used_time_aggregator}(${var.memory_used_timeframe}):
+      avg:docker.mem.in_use${module.filter-tags.query_alert} by {container_name} * 100
+    > ${var.memory_used_threshold_critical}
+EOQ
+
+  thresholds = {
+    warning  = var.memory_used_threshold_warning
+    critical = var.memory_used_threshold_critical
+  }
+
+  evaluation_delay    = var.evaluation_delay
+  new_host_delay      = var.new_host_delay
+  notify_no_data      = false
+  renotify_interval   = 0
+  notify_audit        = false
+  timeout_h           = 0
+  include_tags        = true
+  locked              = false
+  require_full_window = true
+
+  tags = concat(["env:${var.environment}", "type:docker", "provider:docker", "resource:docker", "team:claranet", "created-by:terraform"], var.memory_used_extra_tags)
+
+  lifecycle {
+    ignore_changes = ["silenced"]
+  }
+}
+

caas/docker/outputs.tf

@@ -0,0 +1,10 @@
+output "memory_used_id" {
+  description = "id for monitor memory_used"
+  value       = datadog_monitor.memory_used.*.id
+}
+
+output "not_responding_id" {
+  description = "id for monitor not_responding"
+  value       = datadog_monitor.not_responding.*.id
+}
+